The New Look for IIS.NET
Following up on today's public release of Microsoft Windows Server 2012 and Internet Information Services 8.0, you'll notice some big changes on the IIS.net website.
Over the past few months, we've been working hard with several partners to roll out a brand-new design for the IIS.net website that resembles more closely the look and feel of our websites for Microsoft Azure, Windows Server 2012, and Visual Studio 2012.
Let us know what you think!
Windows Server 2012 and IIS 8 are now available!
Microsoft has just released Windows Server 2012! You can find out more about this release on the Official Windows Server 2012 Launch Website (http://www.windows-server-launch.com).
In tandem with the release of Windows Server 2012, the IIS team is happy to announce the general availability of Internet Information Services 8.0 This new version of IIS offers a wealth of new features and improvements, and here are just a few of the enhancements that you can expect in IIS 8.0: Application Initialization, Dynamic IP Address Restrictions, Centralized SSL Certificate Store, CPU Throttling, FTP Logon Attempt Restrictions, Server Name Indication (SNI) Support, Improved SSL and Configuration Scalability, support for Multicore Scaling on NUMA Hardware, and more! Additional information about IIS 8.0 is available in the "What's New in IIS 8.0 for Windows 8?" web page.
If you'd like to try IIS 8.0 for yourself, you can download the evaluation version and start experimenting today!
Note: This blog was originally posted at http://blogs.msdn.com/robert_mcmurray/
Video: What's New with Internet Information Services (IIS) 8: Performance, Scalability, and Security Features
The folks in the TechEd group have uploaded the video from my "What's New with Internet Information Services (IIS) 8: Performance, Scalability, and Security Features" presentation to YouTube, so you can view the video online.
You can also download the slides and the WMV/MP4 for my presentation at the following URL:
http://channel9.msdn.com/Events/TechEd/NorthAmerica/2012/WSV332
One quick side note: around 38:55 during the video, I had just asked the audience if anyone had used the IIS Configuration Editor, when a tremendous thunderclap resounded outside - this prompted a great laugh from audience members. After the presentation had ended, a couple people came up and jokingly asked how I had managed to stage that so well.
How to create an HTML Application to configure your WebDAV Redirector settings
I've mentioned in previous blog posts that I use the Windows WebDAV Redirector a lot. (And believe me, I use it a lot.) Having said that, there are a lot of registry settings that control how the Windows WebDAV Redirector operates, and I tend to tweak those settings fairly often.
I documented all of those registry settings in my Using the WebDAV Redirector walkthrough, but unfortunately there isn't a built-in interface for managing the settings. With that in mind, I decided to write my own user interface.
I knew that it would be pretty simple to create a basic Windows Form application that does everything, but my trouble is that I would want to share the code in a blog, and the steps create a Windows application are probably more than I would want to write in such a short space. So I decided to reach into my scripting past and create an HTML Application for Windows that configures all of the Windows WebDAV Redirector settings.
It should be noted, like everything else these days, that this code is provided as-is. ;-]
Using the HTML Application
When you run the application, it will present you with the following user interface, which allows you to configure most of the useful Windows WebDAV Redirector settings:
Creating the HTML Application
To create this HTML Application, save the following HTMLA code as "WebDAV Redirector Settings.hta" to your computer, and then double-click its icon to run the application.
<html>
<head>
<title>WebDAV Redirector Settings</title>
<HTA:APPLICATION
APPLICATIONNAME="WebDAV Redirector Settings"
ID="WebDAV Redirector Settings"
VERSION="1.0"
BORDER="dialog"
BORDERSTYLE="static"
INNERBORDER="no"
SYSMENU="no"
MAXIMIZEBUTTON="no"
MINIMIZEBUTTON="no"
SCROLL="no"
SCROLLFLAT="yes"
SINGLEINSTANCE="yes"
CONTEXTMENU="no"
SELECTION="no"/>
<script language="vbscript">
' ----------------------------------------
' Start of main code section.
' ----------------------------------------
Option Explicit
Const intDialogWidth = 700
Const intDialogHeight = 620
Const HKEY_LOCAL_MACHINE = &H80000002
Const strWebClientKeyPath = "SYSTEM\CurrentControlSet\Services\WebClient\Parameters"
Const strLuaKeyPath = "Software\Microsoft\Windows\CurrentVersion\Policies\System"
Dim objRegistry
Dim blnHasChanges
' ----------------------------------------
' Start the application.
' ----------------------------------------
Sub Window_OnLoad
On Error Resume Next
' Set up the UI dimensions.
Self.resizeTo intDialogWidth,intDialogHeight
Self.moveTo (Screen.AvailWidth - intDialogWidth) / 2, _
(Screen.AvailHeight - intDialogHeight) / 2
' Retrieve the current settings.
Document.all.TheBody.ClassName = "hide"
Set objRegistry = GetObject( _
"winmgmts:{impersonationLevel=impersonate}!\\.\root\default:StdRegProv")
Call CheckForLUA()
Call GetValues()
Document.All.TheBody.ClassName = "show"
End Sub
' ----------------------------------------
' Check for User Access Control
' ----------------------------------------
Sub CheckForLUA()
If GetRegistryDWORD(strLuaKeyPath,"EnableLUA",1)<> 0 Then
MsgBox "User Access Control (UAC) is enabled on this computer." & _
vbCrLf & vbCrLf & "UAC must be disabled in order to edit " & _
"the registry and restart the service for the WebDAV Redirector. " & _
"Please disable UAC before running this application again. " & _
"This application will now exit.", _
vbCritical, "User Access Control"
Self.close
End If
End Sub
' ----------------------------------------
' Exit the application.
' ----------------------------------------
Sub ExitApplication()
If blnHasChanges = False Then
If MsgBox("Are you sure you want to exit?", _
vbQuestion Or vbYesNo Or vbDefaultButton2, _
"Exit Application") = vbNo Then
Exit Sub
End If
Else
Dim intRetVal
intRetVal = MsgBox("You have unsaved changes. " & _
"Do you want to save them before you exit?", _
vbQuestion Or vbYesNoCancel Or vbDefaultButton1, _
"Exit Application")
If intRetVal = vbYes Then
Call SetValues()
ElseIf intRetVal = vbCancel Then
Exit Sub
End If
End If
Self.close
End Sub
' ----------------------------------------
' Flag the application as having changes.
' ----------------------------------------
Sub FlagChanges()
blnHasChanges = True
End Sub
' ----------------------------------------
' Retrieve the settings from the registry.
' ----------------------------------------
Sub GetValues()
On Error Resume Next
Dim tmpCount,tmpArray,tmpString
' Get the radio button values
Call SetRadioValue(Document.all.BasicAuthLevel, _
GetRegistryDWORD(strWebClientKeyPath, _
"BasicAuthLevel",1))
Call SetRadioValue(Document.all.SupportLocking, _
GetRegistryDWORD(strWebClientKeyPath, _
"SupportLocking",1))
' Get the text box values
Document.all.InternetServerTimeoutInSec.Value = _
GetRegistryDWORD(strWebClientKeyPath, _
"InternetServerTimeoutInSec",30)
Document.all.FileAttributesLimitInBytes.Value = _
GetRegistryDWORD(strWebClientKeyPath, _
"FileAttributesLimitInBytes",1000000)
Document.all.FileSizeLimitInBytes.Value = _
GetRegistryDWORD(strWebClientKeyPath, _
"FileSizeLimitInBytes",50000000)
Document.all.LocalServerTimeoutInSec.Value = _
GetRegistryDWORD(strWebClientKeyPath, _
"LocalServerTimeoutInSec",15)
Document.all.SendReceiveTimeoutInSec.Value = _
GetRegistryDWORD(strWebClientKeyPath, _
"SendReceiveTimeoutInSec",60)
Document.all.ServerNotFoundCacheLifeTimeInSec.Value = _
GetRegistryDWORD(strWebClientKeyPath, _
"ServerNotFoundCacheLifeTimeInSec",60)
' Get the text area values
tmpArray = GetRegistryMULTISZ( _
strWebClientKeyPath,"AuthForwardServerList")
For tmpCount = 0 To UBound(tmpArray)
tmpString = tmpString & tmpArray(tmpCount) & vbTab
Next
If Len(tmpString)>0 Then
Document.all.AuthForwardServerList.Value = _
Replace(Left(tmpString,Len(tmpString)-1),vbTab,vbCrLf)
End If
blnHasChanges = False
End Sub
' ----------------------------------------
' Save the settings in the registry.
' ----------------------------------------
Sub SetValues()
On Error Resume Next
' Set the radio button values
Call SetRegistryDWORD( _
strWebClientKeyPath, _
"BasicAuthLevel", _
GetRadioValue(Document.all.BasicAuthLevel))
Call SetRegistryDWORD( _
strWebClientKeyPath, _
"SupportLocking", _
GetRadioValue(Document.all.SupportLocking))
' Set the text box values
Call SetRegistryDWORD( _
strWebClientKeyPath, _
"InternetServerTimeoutInSec", _
Document.all.InternetServerTimeoutInSec.Value)
Call SetRegistryDWORD( _
strWebClientKeyPath, _
"FileAttributesLimitInBytes", _
Document.all.FileAttributesLimitInBytes.Value)
Call SetRegistryDWORD( _
strWebClientKeyPath, _
"FileSizeLimitInBytes", _
Document.all.FileSizeLimitInBytes.Value)
Call SetRegistryDWORD( _
strWebClientKeyPath, _
"LocalServerTimeoutInSec", _
Document.all.LocalServerTimeoutInSec.Value)
Call SetRegistryDWORD( _
strWebClientKeyPath, _
"SendReceiveTimeoutInSec", _
Document.all.SendReceiveTimeoutInSec.Value)
Call SetRegistryDWORD( _
strWebClientKeyPath, _
"ServerNotFoundCacheLifeTimeInSec", _
Document.all.ServerNotFoundCacheLifeTimeInSec.Value)
' Set the text area values
Call SetRegistryMULTISZ( _
strWebClientKeyPath, _
"AuthForwardServerList", _
Split(Document.all.AuthForwardServerList.Value,vbCrLf))
' Prompt to restart the WebClient service
If MsgBox("Do you want to restart the WebDAV Redirector " & _
"service so your settings will take effect?", _
vbQuestion Or vbYesNo Or vbDefaultButton2, _
"Restart WebDAV Redirector") = vbYes Then
' Restart the WebClient service.
Call RestartWebClient()
End If
Call GetValues()
End Sub
' ----------------------------------------
' Start the WebClient service.
' ----------------------------------------
Sub RestartWebClient()
On Error Resume Next
Dim objWMIService,colServices,objService
Document.All.TheBody.ClassName = "hide"
Set objWMIService = GetObject( _
"winmgmts:{impersonationLevel=impersonate}!\\.\root\cimv2")
Set colServices = objWMIService.ExecQuery( _
"Select * from Win32_Service Where Name='WebClient'")
For Each objService in colServices
objService.StopService()
objService.StartService()
Next
Document.All.TheBody.ClassName = "show"
End Sub
' ----------------------------------------
' Retrieve a DWORD value from the registry.
' ----------------------------------------
Function GetRegistryDWORD( _
ByVal tmpKeyPath, _
ByVal tmpValueName, _
ByVal tmpDefaultValue)
On Error Resume Next
Dim tmpDwordValue
If objRegistry.GetDWORDValue( _
HKEY_LOCAL_MACHINE, _
tmpKeyPath, _
tmpValueName, _
tmpDwordValue)=0 Then
GetRegistryDWORD = CLng(tmpDwordValue)
Else
GetRegistryDWORD = CLng(tmpDefaultValue)
End If
End Function
' ----------------------------------------
' Set a DWORD value in the registry.
' ----------------------------------------
Sub SetRegistryDWORD( _
ByVal tmpKeyPath, _
ByVal tmpValueName, _
ByVal tmpDwordValue)
On Error Resume Next
Call objRegistry.SetDWORDValue( _
HKEY_LOCAL_MACHINE, _
tmpKeyPath, _
tmpValueName, _
CLng(tmpDwordValue))
End Sub
' ----------------------------------------
' Retrieve a MULTISZ value from the registry.
' ----------------------------------------
Function GetRegistryMULTISZ( _
ByVal tmpKeyPath, _
ByVal tmpValueName)
On Error Resume Next
Dim tmpMultiSzValue
If objRegistry.GetMultiStringValue( _
HKEY_LOCAL_MACHINE, _
tmpKeyPath, _
tmpValueName, _
tmpMultiSzValue)=0 Then
GetRegistryMULTISZ = tmpMultiSzValue
Else
GetRegistryMULTISZ = Array()
End If
End Function
' ----------------------------------------
' Set a MULTISZ value in the registry.
' ----------------------------------------
Sub SetRegistryMULTISZ( _
ByVal tmpKeyPath, _
ByVal tmpValueName, _
ByVal tmpMultiSzValue)
On Error Resume Next
Call objRegistry.SetMultiStringValue( _
HKEY_LOCAL_MACHINE, _
tmpKeyPath, _
tmpValueName, _
tmpMultiSzValue)
End Sub
' ----------------------------------------
' Retrieve the value of a radio button group.
' ----------------------------------------
Function GetRadioValue(ByVal tmpRadio)
On Error Resume Next
Dim tmpCount
For tmpCount = 0 To (tmpRadio.Length-1)
If tmpRadio(tmpCount).Checked Then
GetRadioValue = CLng(tmpRadio(tmpCount).Value)
Exit For
End If
Next
End Function
' ----------------------------------------
' Set the value for a radio button group.
' ----------------------------------------
Sub SetRadioValue(ByVal tmpRadio, ByVal tmpValue)
On Error Resume Next
Dim tmpCount
For tmpCount = 0 To (tmpRadio.Length-1)
If CLng(tmpRadio(tmpCount).Value) = CLng(tmpValue) Then
tmpRadio(tmpCount).Checked = True
Exit For
End If
Next
End Sub
' ----------------------------------------
'
' ----------------------------------------
Sub Validate(tmpField)
Dim tmpRegEx, tmpMatches
Set tmpRegEx = New RegExp
tmpRegEx.Pattern = "[0-9]"
tmpRegEx.IgnoreCase = True
tmpRegEx.Global = True
Set tmpMatches = tmpRegEx.Execute(tmpField.Value)
If tmpMatches.Count = Len(CStr(tmpField.Value)) Then
If CDbl(tmpField.Value) => 0 And _
CDbl(tmpField.Value) =< 4294967295 Then
Exit Sub
End If
End If
MsgBox "Please enter a whole number between 0 and 4294967295.", _
vbCritical, "Validation Error"
tmpField.Focus
End Sub
' ----------------------------------------
'
' ----------------------------------------
Sub BasicAuthWarning()
MsgBox "WARNING:" & vbCrLf & vbCrLf & _
"Using Basic Authentication over non-SSL connections can cause " & _
"serious security issues. Usernames and passwords are transmitted " & _
"in clear text, therefore the use of Basic Authentication with " & _
"WebDAV is disabled by default for non-SSL connections. That " & _
"being said, this setting can override the default behavior for " & _
"Basic Authentication, but it is strongly discouraged.", _
vbCritical, "Basic Authentication Warning"
End Sub
' ----------------------------------------
' End of main code section.
' ----------------------------------------
</script>
<style>
body { color:#000000; background-color:#cccccc;
font-family:'Segoe UI',Tahoma,Verdana,Arial; font-size:9pt; }
fieldset { padding:10px; width:640px; }
.button { width:150px; }
.textbox { width:200px; height:22px; text-align:right; }
.textarea { width:300px; height:50px; text-align:left; }
.radio { margin-left:-5px; margin-top: -2px; }
.hide { display:none; }
.show { display:block; }
select { width:300px; text-align:left; }
table { border-collapse:collapse; empty-cells:hide; }
h1 { font-size:14pt; }
th { font-size:9pt; text-align:left; vertical-align:top; padding:2px; }
td { font-size:9pt; text-align:left; vertical-align:top; padding:2px; }
big { font-size:11pt; }
small { font-size:8pt; }
</style>
</head>
<body id="TheBody" class="hide">
<h1 align="center" id="TheTitle" style="margin-bottom:-20px;">WebDAV Redirector Settings</h1>
<div align="center">
<p style="margin-bottom:-20px;"><i><small><b>Note</b>: See <a target="_blank" href="http://learn.iis.net/page.aspx/386/using-the-webdav-redirector/">Using the WebDAV Redirector</a> for additional details.</small></i></p>
<form>
<center>
<table border="0" cellpadding="2" cellspacing="2" style="width:600px;">
<tr>
<td style="width:600px;text-align:left"><fieldset title="Security Settings">
<legend> <b>Security Settings</b> </legend>
These values affect the security behavior for the WebDAV Redirector.<br>
<table style="width:600px;">
<tr title="Specifies whether the WebDAV Redirector can use Basic Authentication to communicate with a server.">
<td style="width:300px">
<table border="0">
<tr>
<td style="width:300px"><b>Basic Authentication Level</b></td>
</tr>
<tr>
<td style="width:300px;"><span style="width:280px;padding-left:20px;"><small><i><b>Note</b>: Using basic authentication can cause <u>serious security issues</u> as the username and password are transmitted in clear text, therefore the use of basic authentication over WebDAV is disabled by default unless the connection is using SSL.</i></small></span></td>
</tr>
</table>
</td>
<td style="width:300px">
<table style="width:300px">
<tr>
<td style="width:020px"><input class="radio" type="radio" value="0" name="BasicAuthLevel" onchange="VBScript:FlagChanges()" id="BasicAuthLevel0"></td>
<td style="width:280px"><label for="BasicAuthLevel0">Basic Authentication is disabled</label></td>
</tr>
<tr>
<td style="width:020px"><input class="radio" type="radio" value="1" checked name="BasicAuthLevel" onchange="VBScript:FlagChanges()" id="BasicAuthLevel1"></td>
<td style="width:280px"><label for="BasicAuthLevel1">Basic Authentication is enabled for SSL web sites only</label></td>
</tr>
<tr>
<td style="width:020px"><input class="radio" type="radio" value="2" name="BasicAuthLevel" onchange="VBScript:FlagChanges()" id="BasicAuthLevel2" onClick="BasicWarning()"></td>
<td style="width:280px"><label for="BasicAuthLevel2">Basic Authentication is enabled for SSL and non-SSL web sites</label></td>
</tr>
</table>
</td>
</tr>
<tr title="Specifies a list of local URLs for forwarding credentials that bypasses any proxy settings. (Note: This requires Windows Vista SP1 or later.)">
<td style="width:300px">
<table border="0">
<tr>
<td style="width:300px"><b>Authentication Forwarding Server List</b></td>
</tr>
<tr>
<td style="width:300px;"><span style="width:280px;padding-left:20px;"><small><i><b>Note</b>: Include one server name per line.</i></small></span></td>
</tr>
</table>
</td>
<td style="width:300px"><textarea class="textarea" name="AuthForwardServerList" onchange="VBScript:FlagChanges()"></textarea></td>
</tr>
<tr title="Specifies whether the WebDAV Redirector supports locking.">
<td style="width:300px"><b>Support for WebDAV Locking</b></td>
<td style="width:300px">
<table style="width:300px">
<tr>
<td style="width:020px"><input class="radio" type="radio" value="1" checked name="SupportLocking" onchange="VBScript:FlagChanges()" id="SupportLocking1"></td>
<td style="width:280px"><label for="SupportLocking1">Enable Lock Support</label></td>
</tr>
<tr>
<td style="width:020px"><input class="radio" type="radio" value="0" name="SupportLocking" onchange="VBScript:FlagChanges()" id="SupportLocking0"></td>
<td style="width:280px"><label for="SupportLocking0">Disable Lock Support</label></td>
</tr>
</table>
</td>
</tr>
</table>
</fieldset> </td>
</tr>
<tr>
<td style="width:600px;text-align:left"><fieldset title="Time-outs">
<legend> <b>Time-outs and Maximum Sizes</b> </legend>
These values affect the behavior for WebDAV Client/Server operations.<br>
<table border="0" style="width:600px;">
<tr title="Specifies the connection time-out for the WebDAV Redirector uses when communicating with non-local WebDAV servers.">
<td style="width:300px"><b>Internet Server Time-out</b> <small>(In Seconds)</small></td>
<td style="width:300px"><input class="textbox" type="text" name="InternetServerTimeoutInSec" onchange="VBScript:FlagChanges()" onblur="VBScript:Validate(Me)" value="30"></td>
</tr>
<tr title="Specifies the connection time-out for the WebDAV Redirector uses when communicating with a local WebDAV server.">
<td style="width:300px"><b>Local Server Time-out</b> <small>(In Seconds)</small></td>
<td style="width:300px"><input class="textbox" type="text" name="LocalServerTimeoutInSec" onchange="VBScript:FlagChanges()" onblur="VBScript:Validate(Me)" value="15"></td>
</tr>
<tr title="Specifies the time-out in seconds that the WebDAV Redirector uses after issuing a request.">
<td style="width:300px"><b>Send/Receive Time-out</b> <small>(In Seconds)</small></td>
<td style="width:300px"><input class="textbox" type="text" name="SendReceiveTimeoutInSec" onchange="VBScript:FlagChanges()" onblur="VBScript:Validate(Me)" value="60"></td>
</tr>
<tr title="Specifies the period of time that a server is cached as non-WebDAV by the WebDAV Redirector. If a server is found in this list, a fail is returned immediately without attempting to contact the server.">
<td style="width:300px"><b>Server Not Found Cache Time-out</b> <small>(In Seconds)</small></td>
<td style="width:300px"><input class="textbox" type="text" name="ServerNotFoundCacheLifeTimeInSec" onchange="VBScript:FlagChanges()" onblur="VBScript:Validate(Me)" value="60"></td>
</tr>
<tr title="Specifies the maximum size in bytes that the WebDAV Redirector allows for file transfers.">
<td style="width:300px"><b>Maximum File Size</b> <small>(In Bytes)</small></td>
<td style="width:300px"><input class="textbox" type="text" name="FileSizeLimitInBytes" onchange="VBScript:FlagChanges()" onblur="VBScript:Validate(Me)" value="50000000"></td>
</tr>
<tr title="Specifies the maximum size that is allowed by the WebDAV Redirector for all properties on a specific collection.">
<td style="width:300px"><b>Maximum Attributes Size</b> <small>(In Bytes)</small></td>
<td style="width:300px"><input class="textbox" type="text" name="FileAttributesLimitInBytes" onchange="VBScript:FlagChanges()" onblur="VBScript:Validate(Me)" value="1000000"></td>
</tr>
</table>
</fieldset> </td>
</tr>
<tr>
<td style="text-align:center">
<table border="0">
<tr>
<td style="text-align:center"><input class="button" type="button" value="Apply Settings" onclick="VBScript:SetValues()">
<td style="text-align:center"><input class="button" type="button" value="Exit Application" onclick="VBScript:ExitApplication()">
</tr>
</table>
</td>
</tr>
</table>
</center>
</form>
</div>
</body>
</html>
Additional Notes
You will need to run this HTML Application as an administrator in order to save the settings and restart the Windows WebDAV Redirector. (Which is listed as the "WebClient" service in your Administrative Tools.)
This HTML Application performs basic validation for the numeric fields, and it prevents you from exiting the application when you have unsaved changes, but apart from that there's not much functionality other than setting and retrieving the registry values. How else can you get away with posting an application in a blog with only 500 lines of code and no compilation required? ;-]
Note: This blog was originally posted at http://blogs.msdn.com/robert_mcmurray/
Why I Won't Buy Another HP Computer
First of all, I have to point out that I have a few friends that work for Hewlett-Packard, so I have to apologize up front for what I'm about to write in this blog. But I just had such a horrible customer support experience with HP that I won't buy from them again.
Why I Bought an HP Computer
I have nothing against HP computers; for several years I used two beefy dual-CPU HP/Compaq ProLiant servers for my web hosting machines. (I loved those computers, and I only replaced those when Windows Server 2008 was released and I thought that it was time to upgrade my servers.)
Recently I decided to replace my aging Dell desktop computer with a newer model. I'm quite partial to Dell computers, because I've always had great experiences with their computers and their company. I had a chance to buy a refurbished HP P6510F computer for a great price, so I decided to take a chance with HP since that particular computer model had a lot of great reviews.
When the computer arrived I did what I always do - I reformatted the hard drive and I installed a brand new copy of Windows from scratch. (I have to do this because all computer companies - HP, Dell, Gateway, etc. - install a bunch of useless garbage software whenever you buy one of their new computers.) The computer ran fine for several weeks, but I'm a person that likes to keep their computer up-to-date, so this past weekend I browsed to HP's website to see if there were any updates.
Upgrading the BIOS
As it turns out, there was a new version of their BIOS that was supposed to resolve issues when waking the computer from sleep mode if you have more than 4GB of memory. I only had 4GB of RAM in the computer, but I was already shopping for another 4GB, so it seemed prudent to install the BIOS update. I downloaded the update and ran their installer. After a couple of minutes a dialog box popped up saying that the update had applied successfully and I needed to reboot my computer, which I did.
That's when everything started to go wrong.
All Heck Breaks Loose
When my computer restarted it immediately hit the infamous Blue Screen of Death (BSOD); something very much like the following illustration:
A problem has been detected and Windows has been shut down to
prevent damage to your computer.
If this is the first time you've seen this Stop error screen,
restart your computer. If this screen appears again, follow
these steps:
Check for viruses on your computer. Remove any newly installed
hard drives or hard drive controllers. Check your hard drive
to make sure it is properly configured and terminated.
Run CHKDSK /F to check for hard drive corruption, and then
restart your computer.
Technical information:
*** STOP: 0x0000007B (0xFFFFF880009A9928,0xFFFFFFFFC0000034,
0x0000000000000000,0x0000000000000000)
|
It didn't matter how many times I tried to reboot, I still got the BSOD. I knew that BIOS updates changed some of the settings, so my natural suspicion was to assume that something in the new BIOS settings was causing the problem. I tweaked a few settings like disabling hardware virtualization and such - but there was still no joy in Mudville. After this I started to assume that perhaps the BIOS updated hadn't actually applied successfully, so I started trying to see if I could get my computer to boot from one of my several WinPE-based utility CD-ROMs and reapply the patch, but all of those also fell victim to the vicious BSOD.
I'll spare you the details of everything else that I tried - both hardware and software - but I finally gave up and decided to call HP's 24x7 technical support number.
The Technical Support Nightmare Begins
For geeks like me, having to call technical support is humiliating enough, but it's made so much worse by having to deal with front-line technical support people. Having spent 10 years in technical support myself, I have a great deal of patience with technical support engineers, but it can still be an aggravating experience. I spent the next half-hour answering mundane questions and following every instruction from HP's Tier 1 technical support script - all of which I had tried before. (At least the parts that actually applied to my situation.) I'm sure that the engineer with whom I was working meant well, but it was clear that she was floundering.
After a while she began to tell me that I didn't need the BIOS patch and that this was all my fault, to which I replied that she was correct - I didn't actually need the BIOS patch right now, but I would need it in the future, but that didn't really matter - the BIOS patch should not cause the BSOD. Besides - I always updated the BIOS in my Dell computers with no problems. (There's a good jab at HP to try yourself sometime.) Then she started to tell me that since I had a different version of Windows than HP had installed on my computer, the BIOS patch was not compatible. I asked her incredulously, "Do you mean to tell me that HP expects their customers to never install a new version of Windows?" She hesitated before replying "No," and then I reiterated my earlier assertion that no matter what, the BIOS patch should not cause the BSOD.
Then she began to tell me that I needed to purchase a system restore DVD from HP to rebuild my system. I was quick to point out that doing so would reformat my hard drive - thereby erasing all of my files - and that I was willing to bet that the problem wouldn't go away since the system restore DVD was probably not going to reset the BIOS back to an earlier version. So in my estimation I would be wasting my money and my time on a suggestion that would ultimately achieve nothing. This is where I lost her - she had no idea what I meant; so after more than an hour of basic troubleshooting with Tier 1 support and lots of time spent on hold, my patience was finally gone, and I asked to speak with someone in HP's Tier 2 support.
The Technical Support Nightmare Continues
I was transferred to a guy in Tier 2 support who discussed my predicament with me, and he seemed to have a much better handle on things. One of the first things that he did was verify that there was no reason that the BIOS update shouldn't work with my version of Windows, to which I replied that I had been trying to tell the earlier engineer the same thing. We looked at several settings, but the problem persisted, and then he suggested that I needed to purchase a system restore DVD from HP to rebuild my system. I restated my earlier claim that I would be wasting my money and my time since I was 99.9% sure that the system restore DVD would not roll back the BIOS version, so he put me on hold while he checked on that.
When he came back he informed me that the system restore DVD would not roll back the BIOS version, so I needed to return the computer to HP in order for them to reset the computer's BIOS to the original factory version. He pointed out that this would be free since the computer was under warranty, and he took my address so HP could send me a box in order to send the computer back to HP for repairs. Once all that was taken care of, we hung up.
My total time on the phone was about two hours. Ugh.
Problem Resolved
The next day I went out to lunch with my good friend, Wade Hilmo, and I related my experience to him. Once I described the symptoms he said, "I'll bet the BIOS update changed the mode for your SATA controller. Switch it from IDE to AHCI or vice-versa and the problem should go away."
Darn. I should have thought of that. ;-]
Sure enough, when I got home that night and I pulled up my BIOS settings, the SATA mode was set to RAID; I switched it to IDE and the BSOD went away. Once I knew what the problem was I found the following Microsoft Knowledge Base article that allowed me to enable AHCI:
Error message when you start a Windows 7 or Windows Vista-based computer after you change the SATA mode of the boot drive: "STOP 0x0000007B INACCESSABLE_BOOT_DEVICE"
http://support.microsoft.com/kb/922976
My thanks to Wade for pointing that out, but Wade's follow-up comment was apropos, "I'm still a bit surprised that neither of the HP folks suggested it." So I decided that I should call HP and let them know what it took to fix the problem.
Back to Technical Support
The next day I called HP Customer Care to have them cancel my open work ticket, which was the polite thing to do since the problem was resolved. Having taken care of that, I thought that I'd give their technical support people the details of what caused the issue and how to fix it. Having worked in technical support, I always liked to know what it took to resolve an issue.
This seemed like such a good idea at the time, but it didn't turn out that way. When I called HP's Customer Care folks transferred the call to their technical support people, one of their idiots support engineers put me on hold for 20-30 minutes while he read the case notes.
Are you kidding me? It doesn't take 20-30 minutes to read the case notes, even if you're in your first year of Hooked on Phonics.
Once he took me off hold, I was pleading with him to listen to my explanation that the problem was already resolved and it was not caused by whatever stupid idea kept popping out of his wild imagination - I just wanted to share the details of how to resolve the issue if another customer calls in with the same problem, which is undoubtedly going to happen. I pointed out that I was trying to help HIM, for Pete's sake, and he just wouldn't listen. (I started hoping that HP was recording the call.)
After all that, I made it abundantly pretty clear that what he did was very unprofessional, and I asked to speak to a manager. He informed me that he'd see if a manager was available - then he put me back on hold. Fortunately I was calling from work where I have a headset for my telephone, this way I could keep working while I was on hold. (Otherwise this would have really aggravated me.)
After another 20-30 minutes I realized that this idiot engineer was not going to find a manager, he was waiting for me to hang up and go away. So I decided to put that call on hold and try to call back into technical support, but my @#$% LG-Nortel phone won't let me call a phone number if I already have that number on hold. Argh. While I was browsing HP's website to see if I could locate a different phone number for technical support I accidently hung up the original call.
Crap, crap, crap.
So I called HP again and I got another engineer - and I asked to speak to a manager right off the bat. I profusely apologized to the new engineer, and I stated emphatically that it was nothing that he did. He asked for my name and such, but I told him that I had a support ticket number and I gave him that instead. Then I started to explain what happened with the other idiot and how I resolved the issue, but this new engineer attempted to defend the earlier idiot engineer and started to change the subject. I politely cut him off and simply pointed out that the first guy took 30 minutes to read the case notes, whereas he took less than 30 seconds - even this guy had to admit that the first guy's behavior was uncalled for.
Cutting the rest of the story short, I did finally tell the new engineer what it took to fix the problem, which was simply resetting the SATA configuration back to the pre-update BIOS value. I also gave him the information about how to enable AHCI using Microsoft's KB 922976. He thanked me for the information, and after he tried unsuccessfully to upsell me on a new warranty for my computer we ended the call.
Closing Remarks
So there you have it - a thoroughly bad HP customer support experience. If either Hewlett or Packard somehow manage to read this blog, they should be ashamed on behalf of their employees. I'd give you the names of those employees, but no one that I talked to had a name that I could pronounce.
Of course, I never did get to speak to a manager at HP.
Disabling Local Loopback Checks on Web Servers that Run IIS
I've run into this situation more times that I can count: I set up a new web server and no matter what I do, I cannot log into websites on the server that require authentication while I am browsing to them from the console. I used to pull my hair out over this problem until I discovered the problem is in the Windows Local Security Authority (LSA) and it can be easily remedied.
- Open your registry editor by going to Start –> Run and enter regedit and click OK.
- Go to
HKEY_LOCAL_MACHINE\SYSTEM\CurrentControlSet\Control\Lsa in the registry editor.
- Right-click Lsa, click on New and select DWORD value.
- Enter DisableLoopbackCheck and press Enter.
- Right-click DisableloopbackCheck and select Modify.
- In the Value data box, enter 1 and click OK.
- Reboot your server.
Several years later someone wrote the following KB article that includes this fix with a description of the problem, as well as an alternate workaround:
http://support.microsoft.com/kb/896861
HTH
Windows 7 Hotkeys
I put together this list for my brother when Windows 7 launched. I got the information from a variety of sources, thereby living up to the old adage that "Copying from one person is plagiarism, copying from a hundred people is research." Some of these are new to Windows 7, while others have been around a little while. In any event, here are some notes that explain how to interpret the keystrokes:
- A plus symbol (+) between keys means to press the keys at the same time, whereas a comma (,) between keys means to press the keys one after another.
- [Right] text stands for the right cursor key, [Left] for the left cursor key, etc.
Taskbar Modifiers
| Shift+Click |
Open a new instance of the program |
| Ctrl+Click |
Cycle between windows in a group |
| Middle Click |
Open a new instance of the program |
| Ctrl+Shift+Click |
Open a new instance of the program as Administrator |
| Shift+Right-Click |
Show window menu |
Managing Windows
| Alt+F4 |
Close the active window |
| Alt+Tab |
Switch to previous active window |
| Alt+Esc |
Cycle through all open windows |
| Win+Tab |
Flip 3D |
| Ctrl+Win+Tab |
Persistent Flip 3D |
| Win+T |
Cycle through applications on taskbar (showing its live preview) |
| Win+M |
Minimize all open windows |
| Win+Shift+M |
Undo all window minimization |
| Win+D |
Toggle showing the desktop |
| Win+P |
Open the projection menu (generally used for laptops connected to projectors) |
| Win+[Up] |
Maximize the current window |
| Win+[Down] |
If the current window is maximized, restore it; if the current window is restored, minimize it |
| Win+[Left] |
Dock the current window to the left half of the screen
• If it is already docked left, it is moved to the right half of the screen
• If it is already docked right, it is restored to its original size |
| Win+[Right] |
Dock the current window to the right half of the screen
• If it is already docked right, it is moved to the left half of the screen
• If it is already docked left, it is restored to its original size |
| Win+Shift+[Left] |
Move current window to the left monitor (with dual monitors) |
| Win+Shift+[Right] |
Move current window to the right monitor (with dual monitors) |
| Win+Home |
Minimize all but the current window |
| Win+Space |
Peek at the desktop |
| Win+[Plus sign] |
Zoom in |
| Win+[Minus sign] |
Zoom out |
Starting Programs
| Win+1 |
Open the first program on your Quick Launch bar |
| Win+2 |
Open the second program on your Quick Launch bar |
| Win+n |
Open the nth program on your Quick Launch bar |
| Win+U |
Open the ease of access center |
| Win+F |
Open the search window |
| Win+X |
Open the Mobility Center |
| Win+E |
Open Explorer |
| Win+R |
Open the Run window |
| Win+B |
Move focus to notification tray (the right-most portion of the taskbar) |
| Win+Pause |
Open the System Properties portion from the Control Panel |
| Ctrl+Shift+Esc |
Open Windows Task Manager |
Logging In And Out
| Win, [Right], Enter |
Shutdown |
| Win, [Right], [Right], R |
Restart |
| Win, [Right], [Right], S |
Sleep |
| Win, [Right], [Right], H |
Hibernate |
| Win, [Right], [Right], W |
Switch Users |
| Win+L |
Locks computer |
Viewing Folders With Explorer
| Alt+[Left] |
Go back |
| Alt+[Right] |
Go forward |
| Alt+[Up] |
Go up a directory |
| Alt+D |
Move focus to address bar |
| Alt+D, Tab |
Move focus to search bar |
| Alt+Enter |
Open the Properties window of the current selection |
| Ctrl+Mousewheel |
Change the view type (extra large, small, list view, detail, etc.) |
| Alt+P |
Show/hide the preview pane |
Batch File: Delete Duplicate Files
Using this Batch File
Some time ago a friend of mine gave me a bunch of JPG files, but for some reason she had two copies of every image in the collection. The names of the images had all been randomized, and since there were hundreds of files in the collection it would have taken hours to find and delete the duplicates. With that in mind, I wrote the following batch file that loops through the collection of files and does a binary comparison to find and delete duplicate files.
To use the example code, copy the batch file code from below into Notepad and save it as "_del_dupes.cmd" in the folder where you have duplicate files
Note: As with many utilities that I write - this is a destructive operation, meaning that it will delete files without prompting, so you should always make a backup just in case something goes terribly wrong... ;-]
Batch File Example Code
@echo off
dir *.jpg /b > _del_dupes.1.txt
for /f "delims=|" %%a in (_del_dupes.1.txt) do (
if exist "%%a" (
dir *.jpg /b > _del_dupes.2.txt
for /f "delims=|" %%b in (_del_dupes.2.txt) do (
if not "%%a"=="%%b" (
echo Comparing "%%a" to "%%b"...
fc /b "%%a" "%%b">NUL
if errorlevel 1 (
echo DIFFERENT
) else (
echo SAME
del "%%b"
)
)
)
)
)
del _del_dupes.?.txt
Testing IIS 7 for Yourself
The momentum for IIS 7 is gradually building, and I keep seeing great things in the press and several blogs about it. You can read a few details below:
IIS 7 contains a number of great features, and there are a couple of ways that you can get your hands on it for testing without installing the Vista or Longhorn Beta:
Have fun!
How to Record Logon Activity in W3C Extended Log File Format using WSH
Many years ago I put together a bunch of information about logging system activity in W3C format by using Group Policy Objects and Windows Script Host. All of that information was supposed to become Microsoft KB article 324414, but I changed teams and I eventually lost track of its status. Recently I had a need for the information in that KB article and discovered that it was never published, so I had to look for my notes to reconstruct what was supposed to be in the KB article, and I thought that all that effort would make a good blog post.
(Note: This blog post has been updated a few times since it was first posted in order to keep it up-to-date.)
IN THIS POST
APPLIES TO
- Windows Server 2008 R2
- Windows 7
- Windows Server 2008
- Windows Vista
- Windows Server 2003 R2
- Windows Server 2003
- Windows XP
- Windows Server 2000
The steps in this blog post will show you how to configure your network for additional logon/logoff information for all domain clients by using a sample Windows Script Host (WSH) script to create log files that conform to the W3C Extended Log File (ExLF) Format.
The W3C Extended Log File Format is currently used on Windows servers by the various web services that install with Internet Information Services. These log files are kept in your %SystemRoot%\System32\LogFiles or %SystemRoot%\Inetsrv\Logs\LogFiles folder. By configuring this sample logging script through a domain-level Group Policy, a new folder named Activity will be created under the %SystemRoot%\System32\LogFiles folder containing log entries formatted like the following example:
#Description: Log file for all LOGON/LOGOFF activity
#Date: 2002-01-01 21:28:50
#Fields: date time s-computername cs-username cs-method
2002-01-01 21:28:50 MYCOMPUTER LOCALHOST\SYSTEM STARTUP
2002-01-01 21:32:55 MYCOMPUTER MYDOMAIN\userone LOGON
2002-01-01 21:45:58 MYCOMPUTER MYDOMAIN\userone LOGOFF
2002-01-01 21:47:00 MYCOMPUTER MYDOMAIN\usertwo LOGON
2002-01-01 21:52:02 MYCOMPUTER MYDOMAIN\usertwo LOGOFF
2002-01-01 21:53:09 MYCOMPUTER LOCALHOST\SYSTEM SHUTDOWN
Since there are a wide variety of applications that can process log files in the W3C Extended Log File Format, recording logs in this format allows domain administrators to use tools they are already familiar with when analyzing network logon/logoff information.
NOTE: The W3C Extended Log File Format requires that all times must be kept in Greenwich Mean Time (GMT). As such, all logon/logoff activity recorded by the script in this article will be listed in GMT. This allows a uniform standard for large-scale networks that traverse multiple time zones.
- Log on to your Windows Domain Controller as a Domain Administrator.
- Open Windows Notepad by clicking Start, then All Programs, then Accessories, and then Notepad.
- Type or paste the following WSH code into notepad:
Option Explicit
On Error Resume Next
' declare all variables
Dim objFSO,objFile
Dim objNet,objShell
Dim objProcess,objArgs
Dim strFolder,strFile
Dim blnFileExists
Dim objDateTime,lngTimeZoneOffset
Dim strYear,strMonth,strDay
Dim strLongDate,strShortDate
Dim strShortTime,strMethod
Dim strComputerName,strUserDomain,strUserName
' create all objects
Set objNet = WScript.CreateObject("WScript.Network")
Set objFSO = WScript.CreateObject("Scripting.FileSystemObject")
Set objShell = WScript.CreateObject("WScript.Shell")
Set objProcess = objShell.Environment("PROCESS")
Set objArgs = WScript.Arguments
' process arguments
If objArgs.Count <> 1 Then WScript.Quit
strMethod = UCase(objArgs(0))
' perform date operations
lngTimeZoneOffset = GetTimeZoneOffset()
objDateTime = Now() - lngTimeZoneOffset
strYear = CStr(Year(objDateTime))
strMonth = Right("00" & CStr(Month(objDateTime)),2)
strDay = Right("00" & CStr(Day(objDateTime)),2)
strLongDate = strYear & "-" & strMonth & "-" & strDay
strShortDate = Right(strYear,2) & strMonth & strDay
strShortTime = FormatDateTime(objDateTime,4) & ":" & Right("00" & CStr(Second(objDateTime)),2)
' get network information
strComputerName = objNet.ComputerName
If Len(strComputerName) = 0 Then strComputerName = "LOCALHOST"
strUserDomain = objNet.UserDomain
If Len(strUserDomain) = 0 Then strUserDomain = "LOCALHOST"
strUserName = objNet.UserName
If Len(strUserName) = 0 Then strUserName = "()"
' get windows directory name
strFolder = objProcess("WINDIR")
' check for and create "System32" folder
strFolder = strFolder & "\System32"
If objFSO.FolderExists(strFolder) = False Then
objFSO.CreateFolder(strFolder)
End If
' check for and create "LogFiles" folder
strFolder = strFolder & "\LogFiles"
If objFSO.FolderExists(strFolder) = False Then
objFSO.CreateFolder(strFolder)
End If
' check for and create "ACTIVITY" folder
strFolder = strFolder & "\ACTIVITY"
If objFSO.FolderExists(strFolder) = False Then
objFSO.CreateFolder(strFolder)
End If
' set up log file name
strFile = "ex" & strShortDate & ".log"
' check if log file exists
blnFileExists = objFSO.FileExists(strFolder & "\" & strFile)
' open or create the log file
Set objFile = objFSO.OpenTextFile(strFolder & "\" & strFile,8,True)
' write headers if new file
If blnFileExists = False Then
objFile.WriteLine "#Description: Log file for all LOGON/LOGOFF activity"
objFile.WriteLine "#Date: " & strLongDate & " " & strShortTime
objFile.WriteLine "#Fields: date time s-computername cs-username cs-method"
End If
' write the log data
objFile.WriteLine strYear & "-" & strMonth & "-" & strDay & " " & _
strShortTime & " " & _
strComputerName & " " & _
strUserDomain & "\" & _
strUserName & " " & _
strMethod
' close the log file
objFile.Close
Function GetTimeZoneOffset()
On Error Resume Next
Dim tmpShell,tmpOffset
Set tmpShell = WScript.CreateObject("WScript.Shell")
tmpOffset = objShell.RegRead("HKLM\SYSTEM\CurrentControlSet\Control\TimeZoneInformation\ActiveTimeBias")
If Len(tmpOffset) = 0 Then
tmpOffset = objShell.RegRead("HKLM\SYSTEM\CurrentControlSet\Control\TimeZoneInformation\Bias")
End If
' set a default offset if none can be determined
If Len(tmpOffset) = 0 Then tmpOffset = "0"
' calculate offset in hours
tmpOffset = (CLng(tmpOffset) * -1) / 60
' calculate offset in 1/24 of a day
tmpOffset = tmpOffset / 24
GetTimeZoneOffset = tmpOffset
End Function
- Save the file:
- Click the File menu, and then Save.
- When the Save As dialog appears, choose your desktop as the destination.
- Enter activity.vbs for the File name.
- Click the Save button.
- Click the File menu, and then Exit to close Notepad.
To use the sample script with the Default Domain Policy Group Policy Object (GPO), you first need to determine the Globally Unique Identifier (GUID) for the GPO. To do so, use the following steps:
- Start the Active Directory Users and Computers snap-in in the Microsoft Management Console (MMC). To do so, click Start, point to All Programs, point to Administrative Tools, and then click Active Directory Users and Computers.
- Right-click your domain, and then click Properties.
- Click the Group Policy tab.
- Highlight the Default Domain Policy, and then click the Properties button:
- The GUID for the GPO will be listed as the Unique name property in the Summary section of the properties dialog.
- The Default Domain Policy GUID will always be {31B2F340-016D-11D2-945F-00C04FB984F9}, if you choose enable logging in a different policy this will be a different GUID.
- Click the Cancel button to close the GPO properties dialog.
- Click the Cancel button to close the domain properties dialog.
To use the sample script with the GPO, you will need to copy the activity.vbs script on your desktop to each of the following paths:
%SystemRoot%\SYSVOL\sysvol\<DOMAIN>\Policies\<GUID>\USER\Scripts\Logon
%SystemRoot%\SYSVOL\sysvol\<DOMAIN>\Policies\<GUID>\USER\Scripts\Logoff
%SystemRoot%\SYSVOL\sysvol\<DOMAIN>\Policies\<GUID>\MACHINE\Scripts\Startup
%SystemRoot%\SYSVOL\sysvol\<DOMAIN>\Policies\<GUID>\MACHINE\Scripts\Shutdown
Where <DOMAIN> is the Fully Qualified Domain Name (FQDN) of your domain, (e.g. mydomain.local ), and <GUID> is the Globally Unique Identifier (GUID) for the Default Domain Policy GPO.
- Start the Active Directory Users and Computers snap-in in the Microsoft Management Console (MMC). To do this, click Start , point to Programs , point to Administrative Tools , and then click Active Directory Users and Computers .
- Right-click your domain, then click Properties .
- Click the Group Policy tab.
- Highlight the Default Domain Policy , then click the Edit button.
- In the console tree, click the plus sign (+) next to the Windows Settings under User Configuration , then highlight Scripts (Logon/Logoff) .
- Add the Logon script:
- In the right pane, double-click the Logon item.
- Click the Add button.
- Click the Browse button.
- Highlight activity.vbs , then click the Open button.
- Type LOGON in the Script Parameters box.
- Click OK to add the script.
- Click OK to close the Logon scripts dialog.
- Add the Logoff script:
- In the right pane, double-click the Logoff item.
- Click the Add button.
- Click the Browse button.
- Highlight activity.vbs , then click the Open button.
- Type LOGOFF in the Script Parameters box.
- Click OK to add the script.
- Click OK to close the Logoff scripts dialog.
- Close the Group Policy Editor.
- Click OK to close the domain properties dialog.
- Start the Active Directory Users and Computers snap-in in the Microsoft Management Console (MMC). To do this, click Start , point to Programs , point to Administrative Tools , and then click Active Directory Users and Computers .
- Right-click your domain, then click Properties .
- Click the Group Policy tab.
- Highlight the Default Domain Policy , then click the Edit button.
- In the console tree, click the plus sign (+) next to the Windows Settings under Computer Configuration , then highlight Scripts (Startup/Shutdown) .
- Add the Startup script:
- In the right pane, double-click the Startup item.
- Click the Add button.
- Click the Browse button.
- Highlight activity.vbs , then click the Open button.
- Type STARTUP in the Script Parameters box.
- Click OK to add the script.
- Click OK to close the Startup scripts dialog.
- Add the Shutdown script:
- In the right pane, double-click the Shutdown item.
- Click the Add button.
- Click the Browse button.
- Highlight activity.vbs , then click the Open button.
- Type SHUTDOWN in the Script Parameters box.
- Click OK to add the script.
- Click OK to close the Shutdown scripts dialog.
- Close the Group Policy Editor.
- Click OK to close the domain properties dialog.
If the Logon Script does not run, you may need to check your network connection speed as the script may not run when you first log on to the network. For additional information on this issue, click the article numbers below to view the articles in the Microsoft Knowledge Base:
302104 The Logon Script Does Not Run During the Initial Logon Process
For more information on the extended log file format, see the specification in the W3C Working Draft at the following URL:
http://www.w3.org/TR/WD-logfile
For additional information on assigning Logon/Logoff Scripts, click the article number below to view the article in the Microsoft Knowledge Base:
322241 HOW TO: Assign Scripts in Windows 2000
For additional information on the Extended Log File Format, click the article numbers below to view the articles in the Microsoft Knowledge Base:
194699 Extended Log File Format Always in GMT
271196 IIS Log File Entries Have the Incorrect Date and Time Stamp
242898 IIS Log File Naming Syntax